#Use to connect to Discord with a token stored in secret file 'plugins/Denizen/secrets.secret' and send a message once connected.
- ~discordconnect id:mybot token:<secret[discord_bot_token]>
- discordmessage id:mybot channel:<[my_log_channel]> "Connected!"

#Use to disconnect from Discord.
- ~discord id:mybot disconnect

#Use to add a role on a user in a Discord guild.
- ~discord id:mybot add_role user:<[user]> role:<[role]> group:<[group]>

#Use to remove a role on a user in a Discord guild.
- ~discord id:mybot remove_role user:<[user]> role:<[role]> group:<[group]>

#Use to set the online status of the bot, and clear the game status.
- ~discord id:mybot status "Minecraft" "status:ONLINE"

#Use to set the game status of the bot.
- ~discord id:mybot status "Minecraft" "status:ONLINE" "activity:PLAYING"

#Use to change the bot's nickname.
- ~discord id:mybot rename "<[nickname]>" group:<[group]>

#Use to give a user a new nickname.
- ~discord id:mybot rename "<[nickname]>" user:<[user]> group:<[group]>

#Use to start typing in a specific channel.
- ~discord id:mybot start_typing channel:<[channel]>

#Bans a user with a reason and deletes all messages sent by the user in the past 2 hours.
- ~discordban id:mybot add user:<[user]> group:<[group]> "reason:Was being mean!" deletion_timeframe:2h

#Bans a user with but does not delete any messages sent and does not have a reason.
- ~discordban id:mybot add user:<[user]> group:<[group]>

#Unbans a user.
- ~discordban id:mybot remove user:<[user]> group:<[group]>

#Use to create a simple slash command without options and save it.
- ~discordcommand create group:<discord[mybot].group[Denizen]> name:hello "description:Hello world!" save:mycmd
- debug log <entry[mycmd].command.name>

#Use to create a global slash command with one option, using definemap.
- definemap options:
    1:
      type: string
      name: animal
      description: Your favorite animal
      required: true
- ~discordcommand id:mybot create name:animal "description:Pick your favorite!" options:<[options]>

#Use to create a channel in a category.
- discordcreatechannel id:mybot group:1234 name:my-channel category:5678

#Use to create a voice channel and log its name upon creation.
- ~discordcreatechannel id:mybot group:1234 name:very-important-channel type:voice save:stuff
- debug log "Created channel '<entry[stuff].channel.name>'"

#Use to create a new thread for a specific message and send a bot message to it.
- ~discordcreatethread id:mybot "name:The bot's awesome thread" message:<context.message> save:thread
- discordmessage id:mybot channel:<entry[thread].created_thread> "Here I made this thread just for you"

#Use to create a new thread in a channel and link to it in some channel.
- ~discordcreatethread id:mybot "name:The bot's awesome thread" parent:<[some_channel]> save:thread
- discordmessage id:mybot channel:<[some_channel]> "I created thread <&lt>#<entry[thread].created_thread.id><&gt>!"

#Use to quickly reply to a slash command interaction.
- discordinteraction reply interaction:<context.interaction> "hello!"

#Use to defer and reply to a slash command interaction.
- ~discordinteraction defer interaction:<context.interaction>
- discordinteraction reply interaction:<context.interaction> <context.options.get[hello].if_null[world]>

#Use to defer and reply to an interaction ephemerally.
- ~discordinteraction defer interaction:<context.interaction> ephemeral:true
- discordinteraction reply interaction:<context.interaction> "Shh, don't tell anyone!"

#Use to message a Discord channel with a copied channel ID.
- discordmessage id:mybot channel:1234 "Hello world!"

#Use to reply to a message from a message received event.
- discordmessage id:mybot reply:<context.message> "Hello world!"

#Use to message an embed to a Discord channel.
- discordmessage id:mybot channel:1234 embed:<discord_embed[title=hi;description=this is an embed!]>

#Use to message a Discord channel and record the new message ID.
- ~discordmessage id:mybot channel:1234 "Hello world!" save:sent
- announce "Sent as <entry[sent].message.id>"

#Use to send a message to a user through a private channel.
- discordmessage id:mybot user:<[user]> "Hello world!"

#Use to send a short and simple text-file message to a channel.
- discordmessage id:mybot channel:<[channel]> attach_files:<map[quote.xml=<&lt>mcmonkey<&gt> haha text files amirite<n>gotta abuse em]>

#Use to send a message and attach a button to it.
- define my_button <discord_button.with_map[style=primary;id=my_button;label=Hello]>
- discordmessage id:mybot channel:<[channel]> rows:<[my_button]> "Hello world!"

#Use to send a message to a Discord channel, then edit it after 5 seconds.
- ~discordmessage id:mybot channel:<[channel]> "Hello world!" save:msg
- wait 5s
- discordmessage id:mybot edit:<entry[msg].message> "Goodbye!"

#Use to send multiple embeds in a single message
- ~discordmessage id:mybot channel:<[channel]> embed:<discord_embed[title=embed 1]>|<discord_embed[title=embed 2]>

#Use to send files in a single message, including an image file, using a MapTag.
- ~fileread path:my_information.yml save:info
- ~fileread path:my_image.png save:image
- definemap files:
    text.txt: Wow! Denizen is so cool!
    info.yml: <entry[info].data>
    my_image.png: <entry[image].data>
- ~discordmessage id:mybot channel:<[channel]> attach_files:<[files]>

#Use to create a modal that only requests one single direct text input.
- definemap rows:
     1:
         1: <discord_text_input.with[id].as[textinput].with[label].as[Type here!].with[style].as[short]>
- discordmodal interaction:<context.interaction> name:example_modal title:Modal! rows:<[rows]>

#Use to react to a previously sent message.
- discordreact id:mybot message:<[some_message]> add reaction:<[my_emoji_id]>

#Use to remove a reaction from a previously sent message.
- discordreact id:mybot message:<[some_message]> remove reaction:<[some_reaction_emoji]>

#Use to clear all reactions from a message.
- discordreact id:mybot message:<[some_message]> clear reaction:all

#Put a user in timeout.
- discordtimeout id:my_bot add user:<[user]> group:<[group]>

#Put a user in timeout for a duration of 3 hours with a reason.
- discordtimeout id:my_bot add user:<[user]> group:<[group]> "reason:Was being troublesome!" duration:3h

#Remove a user from timeout.
- discordtimeout id:my_bot remove user:<[user]> group:<[group]>

# Suggests fruits that are only longer in length than the current input.
on discord command autocomplete name:eat option:fruit:
- define length <context.options.get[fruit].length>
- define fruits <list[lime|apple|orange|blueberry|dragonfruit]>
- determine choices:<[fruits].filter_tag[<[filter_value].length.is_more_than[<[length]>]>]>

# Suggests the 25 best-matching selections from some dataset against the current input.
on discord command autocomplete:
- define value <context.options.get[<context.focused_option>]>
- determine choices:<server.flag[dataset].sort_by_number[difference[<[value]>]].first[25].if_null[<list>]>

# Find out when a message was sent.
- narrate "You wrote <[message].text> at <[message].id.discord_id_to_time.format>"